Функция SetSystemPowerState

Declare Function SetSystemPowerState Lib "kernel32" ( _
        ByVal fSuspend As Long, ByVal fForce As Long) As Long

SetSystemPowerState переводит компьютер в ждущий или спящий режим. Вызывающий процесс должен иметь привилегию SE_SHUTDOWN_NAME. Для этого используйте функцию AdjustTokenPrivileges. Функция схожа с функцией SetSuspendState. Приложения, написанные для Windows Vista и выше должны использовать именно SetSuspendState.

Возвращаемое значение

If power has been suspended and subsequently restored, the return value is nonzero. If the system was not suspended, the return value is zero. Для получения расширенной информации об ошибке используйте функцию GetLastError.

Параметры

fSuspend

Если параметр равен TRUE, система переходит в suspended. Если параметр равен FALSE, то система hibernates.

fForce

Параметр игнорируется

Пример

Private Const ANYSIZE_ARRAY = 1
Private Const TOKEN_ADJUST_PRIVILEGES = &H20
Private Const TOKEN_QUERY = &H8
Private Const SE_PRIVILEGE_ENABLED = &H2

Private Type LUID
    LowPart As Long
    HighPart As Long
End Type

Private Type LUID_AND_ATTRIBUTES
    pLuid As LUID
    Attributes As Long
End Type

Private Type TOKEN_PRIVILEGES
    PrivilegeCount As Long
    Privileges(ANYSIZE_ARRAY) As LUID_AND_ATTRIBUTES
End Type

Private Declare Function SetSystemPowerState Lib "kernel32" (ByVal fSuspend As Long, ByVal fForce As Long) As Long
Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, ByVal lpName As String, lpLuid As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long

'set the shut down privilege for the current application
Private Sub EnableShutDown()
    Dim hProc As Long
    Dim hToken As Long
    Dim mLUID As LUID
    Dim mPriv As TOKEN_PRIVILEGES
    Dim mNewPriv As TOKEN_PRIVILEGES
    hProc = GetCurrentProcess()
    OpenProcessToken hProc, TOKEN_ADJUST_PRIVILEGES + TOKEN_QUERY, hToken
    LookupPrivilegeValue "", "SeShutdownPrivilege", mLUID
    mPriv.PrivilegeCount = 1
    mPriv.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED
    mPriv.Privileges(0).pLuid = mLUID
    ' enable shutdown privilege for the current application
    AdjustTokenPrivileges hToken, False, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount)
End Sub

Private Sub Form_Load()
    'enable the shutdown privilege
    EnableShutDown
    'on Windows2000: hibernate
    'on Windows9x/ME: suspend
    SetSystemPowerState False, False
End Sub

Смотри также

Категория